Нужна помощь !

[W1ndows]

Всем привет, после установки Mgfuncs 4.3 ! Наткнулся на такую проблему, при запуске игры выбивает данную ошибку, хотел бы знать, что нужно сделать, что бы её исправить ! Уже раз 100 переустанавливал гта, не помогает !

 

[Dark_Knight]

Если при запуске SAMP у вас возникает ошибка: Microsoft Visual C++ Runtime Library​

​

​

Единственное решение этой проблемы: Создаём нового пользователя Windows!​

( Перед созданием нового пользователя убедитесь в установке всех библиотек Microsoft Visual C++ )​

​

Если новый пользователь не помог сноси винду

 

[san0]

Можно попробовать запустить этот батник, мб поможет

 

[W1ndows]

Можно попробовать запустить этот батник, мб поможет

что именно исправляет этот батник ?

 

[Dark_Knight]

что именно исправляет этот батник ?

@echo off
echo *******************************************************************************
echo ********************************* Global zone *********************************
echo **************************** http://globalzone.su/ ****************************
echo *******************************************************************************
echo .
 
set BACK_FOLDER=backup
set REG_PATH=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders
set DIR_PATH=%APPDATA%\Microsoft
set BINDDIR=%~dp0
cd /D "%BINDDIR%"
 
IF EXIST "%BINDDIR%\%BACK_FOLDER%" RMDIR /S /Q "%BINDDIR%\%BACK_FOLDER%"
MKDIR "%BINDDIR%\%BACK_FOLDER%"
 
echo В этой папки находятся резервные копии реестра и папок хранилища ключей CryptoApi. >> %BACK_FOLDER%\readme.doc
echo В случае возникновения проблем, вы можете откатить все изменения, используя данные их этой папки. >> %BACK_FOLDER%\readme.doc
echo 'reg_dump.reg' - Резервная копия реестра. Для восстановления просто запустите файл. >> %BACK_FOLDER%\readme.doc
echo 'Crypto' - Резервная копия хранилища ключей. Для восстановления запустите файл: RestoreKeystore.cmd >> %BACK_FOLDER%\readme.doc
echo ----- >> %BACK_FOLDER%\readme.doc
echo Автор скрипта: Dragon_Knight >> %BACK_FOLDER%\readme.doc
echo При поддержи dimonml и сайта: http://forum.sa-mp.com/ >> %BACK_FOLDER%\readme.doc
 
REG EXPORT "%REG_PATH%" %BACK_FOLDER%/reg_dump.reg
REG DELETE "%REG_PATH%" /f
REG ADD "%REG_PATH%" /v "AppData" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Application Data" /f
REG ADD "%REG_PATH%" /v "Cache" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Local Settings\Temporary Internet Files" /f
REG ADD "%REG_PATH%" /v "Cookies" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Cookies" /f
REG ADD "%REG_PATH%" /v "Desktop" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Рабочий стол" /f
REG ADD "%REG_PATH%" /v "Favorites" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Избранное" /f
REG ADD "%REG_PATH%" /v "History" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Local Settings\History" /f
REG ADD "%REG_PATH%" /v "Local AppData" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Local Settings\Application Data" /f
REG ADD "%REG_PATH%" /v "Local Settings" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Local Settings" /f
REG ADD "%REG_PATH%" /v "My Pictures" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Мои документы\Мои рисунки" /f
REG ADD "%REG_PATH%" /v "NetHood" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\NetHood" /f
REG ADD "%REG_PATH%" /v "Personal" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Мои документы" /f
REG ADD "%REG_PATH%" /v "PrintHood" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\PrintHood" /f
REG ADD "%REG_PATH%" /v "Programs" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Главное меню\Программы" /f
REG ADD "%REG_PATH%" /v "SendTo" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\SendTo" /f
REG ADD "%REG_PATH%" /v "Start Menu" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Главное меню" /f
REG ADD "%REG_PATH%" /v "Startup" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Главное меню\Программы\Автозагрузка" /f
REG ADD "%REG_PATH%" /v "Templates" /t REG_EXPAND_SZ /d "%%USERPROFILE%%\Шаблоны" /f
REG ADD "%REG_PATH%\New" /ve
 
echo .
echo Возможно, стоит почистить и пересоздать папки хранилища ключей.
echo Будет создана резервная копия текущий ключей в папке: '%BACK_FOLDER%'.
set /p keystore=Почистить хранилище ключей? (Y\N): 
if /i "%keystore%" == "y" (
 XCOPY "%DIR_PATH%\Crypto" "%BACK_FOLDER%\Crypto" /E /I /Q /H /R /K /Y
 RMDIR /S /Q "%DIR_PATH%\Crypto"
 MKDIR "%DIR_PATH%\Crypto\RSA"
 
 echo @echo off >> %BACK_FOLDER%\RestoreKeystore.cmd
 echo set BINDDIR=%%~dp0 >> %BACK_FOLDER%\RestoreKeystore.cmd
 echo cd /D "%%BINDDIR%%" >> %BACK_FOLDER%\RestoreKeystore.cmd
 echo RMDIR /S /Q "%DIR_PATH%\Crypto" >> %BACK_FOLDER%\RestoreKeystore.cmd
 echo XCOPY "Crypto" "%DIR_PATH%\Crypto" /E /I /Q /H /R /K /Y >> %BACK_FOLDER%\RestoreKeystore.cmd
 echo pause >> %BACK_FOLDER%\RestoreKeystore.cmd
 echo exit >> %BACK_FOLDER%\RestoreKeystore.cmd
)
 
echo .
echo *******************************************************************************
echo ********* Если выше не было ошибок, то все операции завершены успешно *********
echo ***** Можно пользоваться компьютером, но рекомендуется его перезагрузить ******
echo *******************************************************************************
echo .
set /p reboot=Перезагрузить сейчас? (Y\N): 
if /i "%reboot%" == "y" (
 shutdown -r -t 30 -c "Сейчас компьютер будет перезагружен. Убедитесь, что все программы закрыты, а все документы сохранены."
)
 
exit