Cleo вылетает на пляж

[yara_sist228]

Когда выполнение скрипта доходит до этого опкода 0AF9: samp say_msg начинают лететь варнинги и вылетает на пляж. Как исправить?

 

[D3.Pheonix]

Без кода нет помощи

 

[yara_sist228]

{$CLEO .cs}
Thread "Binder"
8AF7: not get_samp_base_to 29@
:2
wait 400
0AFA: is_samp_structures_available 
jf @2

:1
wait 0
if
0ADC: test_cheat "MSK"
jf @1
wait 1000
0AF9: samp say_msg "/mask"
jump @1

 

[Himura]

{$CLEO .cs}
Thread "Binder"
8AF7: not get_samp_base_to 29@
:2
wait 400
0AFA: is_samp_structures_available
jf @2

:1
wait 0
if
0ADC: test_cheat "MSK"
jf @1
wait 1000
0AF9: samp say_msg "/mask"
jump @1

На букву K ничего не забиндено? Может в собейте что-то срабатывает и конфликтует?

 

[yara_sist228]

На букву K ничего не забиндено? Может в собейте что-то срабатывает и конфликтует?

Ничего не установлено, пробовал не только у себя.

 

[0x73616D]

Without SAMPFUNCS

{$CLEO}

0000: NOP

Thread "Binder"

REPEAT
WAIT 1000
    0A8D: 31@ = readMem 0xC8D4C0 sz 4 vp 0
UNTIL 31@ == 9 // SAMP_IS_READY

0AC8: 1@ = allocate_memory_size 1024
0AD3: 1@ = format "/mask"

WHILE TRUE
WAIT 0

IF
0ADC: test_cheat "MSK"
THEN
    WAIT 1000
    0AB1: @get_samp_version_id 0 _returned: ID 0@
    0AB1: @SEND_CMD 2 SampVersionID 0@ Text 1@
    WAIT 137
END

END // END WHILE TRUE

:get_samp_version_id
{
    0AB1: @get_samp_version_id 0 _returned: ID 0@
}
30@ = 0
IF 0AA2: 31@ = "samp.dll" // IF and SET
THEN
    31@ += 0x128
    0A8D: 29@ = read_memory 31@ size 4 virtual_protect 1
    IF 29@ == 0x5542F47A
    THEN // 0.3.7 R1
        30@ = 1
    END
   
    IF 29@ == 0x59C30C94
    THEN // 0.3.7 R2
        30@ = 2
    END
   
    IF 29@ == 0x5A6A3130
    THEN // 0.3.DL
        30@ = 3
    END
   
    31@ -= 8 // reading samp.dll + 0x120
    0A8D: 29@ = read_memory 31@ size 4 virtual_protect 1
   
    IF 29@ == 0x5C0B4243
    THEN // 0.3.7 R3
        30@ = 4
    END
   
    IF 29@ == 0x5DD606CD
    THEN // 0.3.7 R4
        30@ = 5
    END
   
    IF 29@ == 0x6094ACAB
    THEN // 0.3.7 R4 - v2
        30@ = 6
    END
END
0AB2: ret 1 30@

:SEND_CMD
{
    0AC8: 1@ = allocate_memory_size 1024
    0AD3: 1@ = format "/cmds"
    0AB1: @SEND_CMD 2 SampVersionID 0@ Text 1@
}
IF 0AA2: 2@ = "samp.dll"
THEN
    IF NOT 0@ < 0
    THEN
        IF 0@ == 1 // 0.3.7 R1
        THEN    
            0A8E: 3@ = 2@ + 0x65C60
            0AA5: call 3@ num_param 1 pop 0 1@
        END
       
        IF 0@ == 2 // 0.3.7 R2
        THEN    
            0A8E: 3@ = 2@ + 0x65D30
            0AA5: call 3@ num_param 1 pop 0 1@
        END
 
        IF 0@ == 3 // 0.3.DL
        THEN    
            0A8E: 3@ = 2@ + 0x69340
            0AA5: call 3@ num_param 1 pop 0 1@
        END
 
        IF 0@ == 4 // 0.3.7 R3
        THEN    
            0A8E: 3@ = 2@ + 0x69190
            0AA5: call 3@ num_param 1 pop 0 1@
        END
 
        IF 0@ == 5 // 0.3.7 R4
        THEN    
            0A8E: 3@ = 2@ + 0x698C0
            0AA5: call 3@ num_param 1 pop 0 1@
        END
       
        IF 0@ == 6 // 0.3.7 R4 - v2
        THEN    
            0A8E: 3@ = 2@ + 0x69900
            0AA5: call 3@ num_param 1 pop 0 1@
        END      
    END
END
0AB2: 0