Кол-во игроков в стриме в правом углу

[gcode]

Отображает кол-во игроков в стриме в правом верхнем углу, не всегда точно и с медленным обновлением, но всё же :) Активация/деактивация: F5

{$CLEO .cs}
0662: NOP "CLEO : Players In Stream"
0662: NOP "gcode: acheats.ru : blasthack.net"
thread "playersinstream"
 
if
    8AF7: get_samp_base_to 33@
then
    0A93: end_custom_thread
end
repeat
    wait 400
until 0AFA: is_samp_structures_available
 
0B5A: get_screen_resolution 28@ 27@
28@ -= 50
 
/* Dialog Start */
0B80: samp 29@ = create_dialog ""
0B91: samp dialog 29@ add_static id 1 text "" pos_XY 28@ 20 size 30 20
0B86: samp dialog 29@ set_visible false
/* Dialog End */
 
while true
    wait 0
    0B2B: samp 24@ = get_player_id_by_actor_handle $PLAYER_ACTOR
    0AC8: 27@ = allocate_memory_size 32
    0AD3: 27@ = format "%d" 26@
    26@ = 0
    0B94: samp dialog 29@ set_control 1 text_to 27@
    0AC9: free_allocated_memory 27@
    for 28@ = 0 to 999
        wait 0
        if
            003B: 28@ == 24@
        then
            Continue
        end
        if
            0B23: samp is_player_connected 28@
        then
            if
                0B20: samp 27@ = actor_handle_from_samp_playerid 28@
            then
                Actor.StorePos(27@,25@,24@,23@)
                if or
                    not 25@ == 0.0
                    not 24@ == 0.0
                    not 23@ == 0.0
                then
                    26@ += 1
                end
            end
        end
        if
            0AB0: key_pressed 116
        then
            if
                30@ == 0
            then
                30@ = 1
                0B86: samp dialog 29@ set_visible true
            else
                30@ = 0
                0B86: samp dialog 29@ set_visible false
            end
            repeat
                wait 0
            until 8AB0: not key_pressed 116
        end
    end
end

 

[Паша1223]

Что такое стрим? :D

И просто вопрос: возможно ли узнать местоположение игрока без всего? Просто по ИДу

 

[gcode]

Что такое стрим? :D

И просто вопрос: возможно ли узнать местоположение игрока без всего? Просто по ИДу

Стрим это зона прорисовки. Можно узнать только координаты в зоне прорисовки на большинстве серверов

 

[Паша1223]

Стрим это зона прорисовки. Можно узнать только координаты в зоне прорисовки на большинстве серверов

Ясно, классный скрипт, лайк поставил:)

 

[_Jumper]

Как ты так быстро ? :D

Возможно будет показывать 1, когда никого нет, т.к я не исключил самого игрока из счётчика)

Как это исправить?

 

[gcode]

Как ты так быстро ? :D


Как это исправить?

Исправил

 

[itsLegend]

А почему не так? :)

{$CLEO .cs}
0662: NOP "CLEO : Players In Stream           "
0662: NOP "gcode: acheats.ru : blasthack.net"
0662: NOP "Optimize: legend2360 ;)              "
thread "playersinstream"
 
if
    8AF7: get_samp_base_to 33@
then
    0A93: end_custom_thread
end
repeat
    wait 400
until 0AFA: is_samp_structures_available
 
0B5A: get_screen_resolution 1@ 2@
1@ -= 50
 
/* Dialog Start */
0B80: samp 0@ = create_dialog ""
0B91: samp dialog 0@ add_static id 1 text "0" pos_XY 1@ 20 size 30 20
0B86: samp dialog 0@ set_visible false
/* Dialog End */
 
0AC8: 4@ = allocate_memory_size 4
 
while true
    wait 0
    if 0AB0: key_pressed 116
    then
        if not Dialog.IsVisible(0@)
        then 0B86: samp dialog 0@ set_visible true
        else 0B86: samp dialog 0@ set_visible false
        end
 
        while 0AB0: key_pressed 116
            wait 0
        end
    end
 
    if Dialog.IsVisible(0@)
    then
        3@ = 0
        for 1@ = 0 to 999 step 1
            if 0B23: samp is_player_connected 1@
            jf continue
 
            0B20: samp 2@ = actor_handle_from_samp_playerid 1@
            if Actor.Defined(2@)
            jf continue
   
            if 803C: not $PLAYER_ACTOR == 2@
            jf continue
 
            3@ += 1
        end
 
        0AD3: 4@ = format "%d" 3@
        0B94: samp dialog 0@ set_control 1 text_to 4@
    end
end

Ссыль: https://www.dropbox.com/s/hxwacobi5403sx3/players_in_stream.cs

Разница: чекает быстрей, код оптимизирован :)

 

[q0_]

Это же все уже есть в samp , зачем это делать то ? :D
Удерживаешь F5 без твоего клео) и там вся информация есть))

 

[_Jumper]

Плохо что обновляется долго.

 

[itsLegend]

Плохо что обновляется долго.

Выше исходник(от меня), чекает быстро.

 

[_Jumper]

Выше исходник(от меня), чекает быстро.

Знать бы что с ним делать

 

[q0_]

Знать бы что с ним делать

Компилировать. :)

 

[_Jumper]

Компилировать. :)

В txt ?

 

[q0_]

В txt ?

в формат ".cs"
Так же называемый CLEO
Программу Sunny Builder скачай (если её нет).
Туда вставь тот код.
И компилируй ;)
Потом скинешь тот файл который в скомпилировал закинь в папку CLEO.

 

[_Jumper]

в формат ".cs"
Так же называемый CLEO
Программу Sunny Builder скачай (если её нет).
Туда вставь тот код.
И компилируй ;)
Потом скинешь тот файл который в скомпилировал закинь в папку CLEO.

У меня там можно компилировать только в txt